Although I have considered recursively scanning for files, I though it is a bit too dangerous
But your batch might be useful for some (especially since the original file is not lost).

And if I put an update out at some point I might make -t/-text options case insensitive.

I've just spent the afternoon re-learning all the stuff about batch files that I forgot years ago and thought the results of this might be useful. Here is a batch file that will run ToUnicode.exe on all the .h and .cpp files in a folder and its sub-folders. Any warning messages that are produced are saved in unicode.log.

By the way, I spent a little while wondering why ToUnicode.exe wasn't working until I looked at the source code and realised the -T option is case sensitive and -t wouldn't work. It may be worth mentioning this somewhere.

Regards

- Roger

::----------------------------------------------------

:: Converts all the .h and .cpp files in the current folder and all subfolders to a unicode version.
:: The unicode version of foo.h is called foo.u.h and similarly the unicode version of foo.cpp is called foo.u.cpp.
:: Any warnings that the conversion program produces can be found in unicode.log

:: See http://www.robvanderwoude.com/ntfor.php for info on using the "for" batch command.
:: See http://shaunedonohue.blogspot.com/2007/09/every-time-i-need-to-redirect-dos.html for info on redirection, including how to redirect stderr to a file.

@echo off

set logfile="unicode.log"

echo Starting Unicode conversion...

echo ToUnicode warning messages >>%logfile%
echo -------------------------- >>%logfile%
echo. >>%logfile%

:: The 2>> is redirecting stderr to %logfile% instead of stdout.
(for /R %%i in (*.h *.cpp) do ToUnicode -T "%%i" "%%~dpni.u%%~xi") 2>>%logfile%

echo. >>%logfile%
echo ----------------------- >>%logfile%
echo End of warning messages >>%logfile%

echo ...finished Unicode conversion